blob: 7f028a899d39c1f0be8476786137814603cf392f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
|
# Maintainer: Alad Wenter <https://github.com/AladW>
# Co-Maintainer: Cedric Girard <cgirard [dot] archlinux [at] valinor [dot] fr>
# Co-Maintainer: zoorat <zoorat [at] protonmail [dot] com>
pkgname=aurutils
pkgver=19.3
pkgrel=1
pkgdesc='helper tools for the arch user repository'
url='https://github.com/AladW/aurutils'
arch=('any')
license=('custom:ISC')
source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/$pkgver.tar.gz")
changelog=aurutils.changelog
install=aurutils.install
sha256sums=('b49636092e17d4daec129fc4cf86a436145c5acc91df80f1e3dd72bf99846ed6')
depends=('git' 'pacutils' 'curl' 'perl' 'perl-json-xs' 'bash')
optdepends=('bash-completion: bash completion'
'zsh: zsh completion'
'devtools: aur-chroot'
'vifm: default pager'
'ninja: aur-sync ninja support'
'bat: view-delta example script'
'git-delta: view-delta example script'
'python-srcinfo: sync-rebuild example script')
build() {
cd "$pkgname-$pkgver"
make AURUTILS_VERSION="$pkgver"
}
package() {
cd "$pkgname-$pkgver"
make AURUTILS_VERSION="$pkgver" PREFIX=/usr ETCDIR=/etc DESTDIR="$pkgdir" install
}
|