blob: 6ad7e1cce7d1eff7aa5af1712ca82ace0904522e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: Tonkku <contact@tonkku.me>
pkgname=authy-snap
pkgver=1.8.3
pkgrel=1
pkgdesc="Two factor authentication desktop application"
arch=('x86_64')
url='https://authy.com/'
provides=('authy')
license=('unknown')
depends=('nss' 'gtk3' 'libxss' 'libdbusmenu-glib')
optdepends=('libappindicator-gtk3: tray icon support')
makedepends=('squashfs-tools')
_snapid="H8ZpNgIoPyvmkgxOWw5MSzsXK1wRZiHn"
_snaprev="5"
source=("https://api.snapcraft.io/api/v1/snaps/download/${_snapid}_${_snaprev}.snap")
sha256sums=('f6be2a19b96a23c626f15f6baa1b51674b84d4f4215495ac6a8155327c9ddbf9')
prepare() {
echo "Extracting snap file..."
unsquashfs -q -f -d "${srcdir}/${pkgname}" "${_snapid}_${_snaprev}.snap"
}
package() {
# Install files
install -d "${pkgdir}/opt/${pkgname}"
cp -r "${srcdir}/${pkgname}/." "${pkgdir}/opt/${pkgname}"
# Desktop Entry
sed -i 's|${SNAP}/meta/gui/icon.png|authy|g' "${pkgdir}/opt/${pkgname}/meta/gui/authy.desktop"
install -Dm644 "${pkgdir}/opt/${pkgname}/meta/gui/authy.desktop" -t "${pkgdir}/usr/share/applications"
install -Dm644 "${pkgdir}/opt/${pkgname}/meta/gui/icon.png" "${pkgdir}/usr/share/pixmaps/authy.png"
# Clean up unnecessary files
rm -rf "$pkgdir/opt/$pkgname"/{data-dir,gnome-platform,lib,meta,scripts,usr,*.sh}
# Symlink binary to /usr/bin
install -d "${pkgdir}/usr/bin"
ln -s "/opt/${pkgname}/authy" "${pkgdir}/usr/bin"
}
|