PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

# Maintainer: Brenek Harrison <brenekharrison @ gmail d0t com>
# Contributor: ston <2424284164@qq.com>

pkgname=auto-editor
pkgver=30.2.0
pkgrel=1
pkgdesc="A command line application for automatically editing video and audio."
url="https://auto-editor.com/"
arch=('x86_64')
license=("Unlicense")
provides=("auto-editor")
conflicts=("auto-editor-bin")
depends=("lame" "gcc-libs" "dav1d" "x264" "ffmpeg" "opus" "libvpx" "svt-av1" "x265" "glibc")
optdepends=(
  'yt-dlp: download and use URLs as inputs'
  'xdg-utils: automatically open completed files with xdg-open')
makedepends=("nim" "git") # git is required to bring in the required Nim version (>=2.2.2)
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/WyattBlue/auto-editor/archive/refs/tags/${pkgver}.tar.gz")
sha256sums=('d24a53c2e8fb6f9e257950f203468569452b7ba1615770ad04c253f2a73a3649')

prepare() {
  cd ${pkgname}-${pkgver}

  # Fixes a build error where Nim generates code that technically works, but causes gcc to error out.
  # Echoing into a file is fine for 29.0.5, but future releases will have an existing nim.conf and some sort of
  # patching will be required, especially since the current nim.conf on master statically builds.
  echo '--passC:"-Wno-incompatible-pointer-types"' >> nim.cfg
  echo '--passC:"-Wl,-z,relro,-z,now"' >> nim.cfg # Build with full relro (Relocation Read-Only)
}

build() {
	cd ${pkgname}-${pkgver}

	export DISABLE_WHISPER="1"
	nimble make
}

package() {
	cd ${pkgname}-${pkgver}

	install -Dm755 "./auto-editor" "${pkgdir}/usr/bin/auto-editor"
}

# vim: ft=sh ts=2 sw=2 et