PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

# Maintainer: Luis Martinez <luis dot martinez at disroot dot org>

pkgbase=autodiff
pkgname=('autodiff' 'python-autodiff')
pkgver=0.6.11
pkgrel=1
pkgdesc="Automatic differentiation made easier for C++"
arch=('any')
url="https://github.com/autodiff/autodiff"
license=('MIT')
makedepends=(
	'catch2'
	'cmake'
	'eigen'
	'pybind11'
	'python-build'
	'python-installer'
	'python-setuptools'
	'python-wheel')
changelog=CHANGELOG.md
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha256sums=('ac7a52387a10ecb8ba77ce5385ffb23893ff9a623467b4392bd204422a3b5c09')

build() {
	cmake \
		-B build \
		-S "$pkgname-$pkgver" \
		-DCMAKE_BUILD_TYPE=None \
		-DCMAKE_INSTALL_PREFIX=/usr \
		-DBUILD_SHARED_LIBS=ON \
		-DAUTODIFF_BUILD_TESTS=ON \
		-DAUTODIFF_BUILD_PYTHON=ON \
		-DAUTODIFF_BUILD_EXAMPLES=OFF
	cmake --build build
	cd build/python/package
	python -m build --wheel --no-isolation
}

check() {
	cmake --build build --target tests
}

package_autodiff() {
	DESTDIR="$pkgdir/" cmake --build build --target install
	install -Dm644 "$pkgname-$pkgver/LICENSE" -t "$pkgdir/usr/share/licenses/$pkgname/"
}

package_python-autodiff() {
	depends=('python')
	arch=('x86_64')
	pkgdesc+=' -- Python bindings'

	PYTHONHASHSEED=0 python -m installer --destdir="$pkgdir" build/python/package/dist/*.whl
	install -Dm644 "$pkgbase-$pkgver/LICENSE" -t "$pkgdir/usr/share/licenses/$pkgname/"
}