blob: 321363ac63edbb7ffc9357380f9c95b2ffe3ccda (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# Maintainer: Hyacinthe Cartiaux <hyacinthe.cartiaux@free.fr>
# Contributor: Alexander Jacocks <alexander@redhat.com>
# Contributor: Alex Stelmachonak <mail@ava1ar.me>
# Contributor: Lukas Fleischer <lfleischer@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Dale Blount <dale@archlinux.org>
# Contributor: Manolis Tzanidakis
# Contributor: Leonid Isaev
_pkgname=autofs
pkgname=autofs-git
pkgver=5.1.9.93.g4da861e1
pkgrel=1
pkgdesc='A kernel-based automounter for Linux'
arch=('x86_64')
url='https://www.kernel.org/pub/linux/daemons/autofs/'
license=('GPL-2.0-or-later')
depends=('libxml2')
makedepends=('git' 'libldap' 'krb5' 'kmod' 'sssd' 'libnsl' 'rpcsvc-proto' 'systemd')
optdepends=('krb5: for LDAP support'
'sssd: for SSSD integration')
provides=('autofs')
conflicts=('autofs')
backup=('etc/autofs/auto.master'
'etc/autofs/auto.misc'
'etc/autofs/auto.net'
'etc/autofs/auto.smb'
'etc/autofs/autofs.conf'
'etc/autofs/autofs_ldap_auth.conf'
'etc/default/autofs')
source=(git+https://git.kernel.org/pub/scm/linux/storage/autofs/autofs.git
autofs-arch-configuration-path.patch)
sha256sums=('SKIP'
'def52bda93a414896c41e587c2ffbefdd360767f938399767b7582d55c329a34')
pkgver() {
cd "${_pkgname}"
git describe --tags --long | sed 's/^release_//;s/[-_]/./g'
}
prepare() {
cd "${_pkgname}"
patch --forward --strip=1 --input=../autofs-arch-configuration-path.patch
}
build() {
cd "${_pkgname}"
./configure --prefix=/usr \
--sysconfdir=/etc/autofs \
--sbindir=/usr/bin \
--with-mapdir=/etc/autofs \
--with-confdir=/etc/default \
--without-hesiod \
--enable-ignore-busy \
--with-libtirpc \
--with-systemd
make
}
package() {
cd "${_pkgname}"
make INSTALLROOT="${pkgdir}" install install_samples
install -dm755 "${pkgdir}/etc/autofs/auto.master.d"
}
|