blob: fc066d929d5bb96b80ac60bb79a7b847df90a69f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: Sven Schwermer <aur@svenschwermer.de>
# Contributor: Thomas Krug <t.krug@elektronenpumpe.de>
# Contributor: Corrado Primier <bardo@aur.archlinux.org>
# Contributor: danst0 <danst0@west.de>
# Contributor: Tim Besard <tim.besard@gmail.com>
pkgname=avr-libc-avrxmega3-svn
_pkgname=avr-libc
pkgver=r2550M
pkgrel=1
pkgdesc="The C runtime library for the AVR family of microcontrollers (incl. avrxmega3 devices)"
arch=('any')
url="http://savannah.nongnu.org/projects/avr-libc/"
license=('BSD')
depends=('avr-gcc')
makedepends=('svn' 'xz')
provides=('avr-libc')
conflicts=('avr-libc')
options=('!strip' 'libtool' 'staticlibs')
source=("$_pkgname"::'svn+http://svn.savannah.nongnu.org/svn/avr-libc/trunk/avr-libc/'
'avrxmega3-v10.diff.xz'::'https://file.savannah.nongnu.org/file/avrxmega3-v10.diff.xz?file_id=48974')
md5sums=('SKIP' '12ca80af092e6b138356287b69f40d2a')
pkgver() {
cd "$srcdir/$_pkgname"
echo r$(svnversion)
}
prepare() {
cd "$srcdir/$_pkgname"
# https://savannah.nongnu.org/patch/?9543
xzcat "$srcdir/avrxmega3-v10.diff.xz" | patch -p0
}
build() {
cd "$srcdir/$_pkgname"
unset CFLAGS
unset CXXFLAGS
unset LDFLAGS
./bootstrap
./configure --build=$(./config.guess) --host=avr --prefix=/usr
make
}
package() {
cd "$srcdir/$_pkgname"
make DESTDIR="$pkgdir" install
install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/"$pkgname"/COPYING
}
# vim:set ts=2 sw=2 et:
|