PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66

# Maintainer: Gustavo Alvarez <sl1pkn07@gmail.com>

pkgbase=avxsynth-git
pkgname=('avxsynth-git' 'avxedit-git')
pkgver=20150407.80dcb7e
pkgrel=1
pkgdesc="Linux Port of AviSynth. (Git version)"
arch=('i686' 'x86_64')
url='http://www.avxsynth.org'
license=('GPL2')
makedepends=('git'
             'yasm'
             'subversion'
             'python2'
             'qt4'
             'mplayer'
             'log4cpp'
             'pango'
             'ffms2'
             )
source=('git+https://github.com/avxsynth/avxsynth.git')
sha1sums=('SKIP')

pkgver() {
  cd avxsynth
  echo "$(git log -1 --format="%cd" --date=short | tr -d '-').$(git log -1 --format="%h")"
}

prepare() {
  cd avxsynth
  autoreconf -if
}

build() {
  cd avxsynth
  ./configure \
    --prefix=/usr \
    --enable-silent-rules \
    --disable-ffms2
  make
}

package_avxsynth-git() {
  pkgdesc="Linux Port of AviSynth. (Git version)"
  depends=('ffms2'
           'ffmpeg'
           'log4cpp'
           'pango'
           )
  provides=('avxsynth')
  conflicts=('avxsynth')

  make -C avxsynth DESTDIR="${pkgdir}" install
  make -C avxsynth/apps/AVXEdit DESTDIR="${pkgdir}" uninstall
}

package_avxedit-git() {
  pkgdesc="Simple Qt4 frontend for create/edit/test AvxSynth scripts. (Git version)"
  depends=('qt4'
           'avxsynth-git'
           )
  provides=('avxedit')
  conflicts=('avxedit')

  make -C avxsynth/apps/AVXEdit DESTDIR="${pkgdir}" install
}