PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75

# Maintainer: Carl Smedstad <carsme@archlinux.org>

pkgname=azure-dev-cli
_pkgname=azure-dev
pkgver=1.8.2
pkgrel=1
pkgdesc="Developer CLI that reduces the time it takes for you to get started on Azure"
arch=(x86_64)
url="https://github.com/Azure/azure-dev"
license=(MIT)
depends=(
  git
  glibc
  kubectl
  python
  terraform
)
makedepends=(go)
source=("$pkgname-$pkgver.tar.gz::$url/archive/azure-dev-cli_$pkgver.tar.gz")
sha256sums=('f60515473c463d51868801166719536a56c88d78a863805848cf96ff0e482aff')

_archive="$_pkgname-azure-dev-cli_$pkgver"

prepare() {
  cd "$_archive"

  go mod download -x
}

build() {
  cd "$_archive"

  export CGO_CPPFLAGS="$CPPFLAGS"
  export CGO_CFLAGS="$CFLAGS"
  export CGO_CXXFLAGS="$CXXFLAGS"
  export CGO_LDFLAGS="$LDFLAGS"
  export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"

  go build -v -buildvcs=false -o azd ./cli/azd/main.go

  # Completions
  ./azd completion bash > azd.bash
  ./azd completion fish > azd.fish
  ./azd completion zsh > azd.zsh
}

check() {
  cd "$_archive"

  # Skip failing tests - not sure why they fail.
  local unit_tests=$(
    go list -buildvcs=false ./... \
      | grep -v 'github.com/azure/azure-dev/cli/azd/internal/scaffold' \
      | grep -v 'github.com/azure/azure-dev/cli/azd/test/cmdrecord' \
      | grep -v 'github.com/azure/azure-dev/cli/azd/test/functional' \
      | sort
  )
  # shellcheck disable=SC2086
  go test -v $unit_tests
}

package() {
  cd "$_archive"

  install -Dm755 -t "$pkgdir/usr/bin" azd

  install -Dm644 azd.bash "$pkgdir/usr/share/bash-completion/completions/azd"
  install -Dm644 azd.fish "$pkgdir/usr/share/fish/vendor_completions.d/azd.fish"
  install -Dm644 azd.zsh "$pkgdir/usr/share/zsh/site-functions/_azd"

  install -Dm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
  cp -a -t "$pkgdir/usr/share/doc/$pkgname" docs

  install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}