blob: 56b8e360d4584f630178dacc83822ba7077003ef (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Maintainer: Carl Smedstad <carsme@archlinux.org>
# Contributor: William Aass Dahlen <cznk@protonmail.com>
pkgname=azure-kubelogin
pkgver=0.1.3
_commit=308f96875c026012123a3b0e95c8fc5473e95a33
pkgrel=1
pkgdesc="A Kubernetes credential (exec) plugin implementing azure authentication"
arch=(x86_64)
url="https://github.com/Azure/kubelogin"
license=(MIT)
depends=(glibc)
makedepends=(
git
go
)
conflicts=(kubelogin)
source=("$pkgname::git+$url.git?signed#commit=$_commit")
sha256sums=('eea093de28893769134fd147557317d555181e77ff4026d40f27e4d72fabb11f')
validpgpkeys=('968479A1AFF927E37D1A566BB5690EEEBB952194') # GitHub <noreply@github.com>
_archive="$pkgname"
pkgver() {
cd "$_archive"
git describe --tags | sed 's/^v//'
}
prepare() {
cd "$_archive"
go mod download -x
}
build() {
cd "$_archive"
export CGO_CPPFLAGS="$CPPFLAGS"
export CGO_CFLAGS="$CFLAGS"
export CGO_CXXFLAGS="$CXXFLAGS"
export CGO_LDFLAGS="$LDFLAGS"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
go build -v .
# Completions
./kubelogin completion bash > kubelogin.bash
./kubelogin completion fish > kubelogin.fish
./kubelogin completion zsh > kubelogin.zsh
}
check() {
cd "$_archive"
# Skip tests failing for some users - not sure why
local unit_tests=$(
go list ./... \
| grep -v 'github.com/Azure/kubelogin/pkg/internal/pop' \
| grep -v 'github.com/Azure/kubelogin/pkg/internal/token' \
| sort
)
# shellcheck disable=SC2086
go test -v $unit_tests
}
package() {
cd "$_archive"
install -Dm755 -t "$pkgdir/usr/bin" kubelogin
install -Dm644 kubelogin.bash "$pkgdir/usr/share/bash-completion/completions/kubelogin"
install -Dm644 kubelogin.fish "$pkgdir/usr/share/fish/vendor_completions.d/kubelogin.fish"
install -Dm644 kubelogin.zsh "$pkgdir/usr/share/zsh/site-functions/_kubelogin"
install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}
|