blob: 358206aa130a2754b8c220985b470c949045ef08 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Maintainer: Carl Smedstad <carl.smedstad at protonmail dot com>
# Contributor: William Aass Dahlen <cznk@protonmail.com>
pkgname=azure-kubelogin
_name=kubelogin
pkgver=0.1.0
pkgrel=1
pkgdesc="A Kubernetes credential (exec) plugin implementing azure authentication"
arch=(x86_64)
url="https://github.com/Azure/kubelogin"
license=(MIT)
depends=(glibc)
makedepends=(
git
go
)
conflicts=(kubelogin)
_commit=0fcd072d45250a50cde855cf50204ad2dc784095 # git rev-parse "$pkgver"
source=("$pkgname::git+$url.git?signed#commit=$_commit")
sha256sums=('SKIP')
validpgpkeys=('5DE3E0509C47EA3CF04A42D34AEE18F83AFDEB23') # GitHub (web-flow commit signing)
_archive="$pkgname"
pkgver() {
cd "$_archive"
git describe --tags | sed 's/^v//'
}
build() {
cd "$_archive"
export CGO_CPPFLAGS="$CPPFLAGS"
export CGO_CFLAGS="$CFLAGS"
export CGO_CXXFLAGS="$CXXFLAGS"
export CGO_LDFLAGS="$LDFLAGS"
export GOFLAGS="-buildmode=pie -trimpath -mod=readonly -modcacherw"
_ld_flags="-linkmode external -X main.gitTag=$pkgver"
go build -ldflags "$_ld_flags" .
# Completions
./kubelogin completion bash > kubelogin.bash
./kubelogin completion fish > kubelogin.fish
./kubelogin completion zsh > kubelogin.zsh
}
check() {
cd "$_archive"
go test ./...
}
package() {
cd "$_archive"
install -Dm755 -t "$pkgdir/usr/bin" kubelogin
install -Dm644 kubelogin.bash "$pkgdir/usr/share/bash-completion/completions/kubelogin"
install -Dm644 kubelogin.fish "$pkgdir/usr/share/fish/vendor_completions.d/kubelogin.fish"
install -Dm644 kubelogin.zsh "$pkgdir/usr/share/zsh/site-functions/_kubelogin"
install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}
|