blob: 85de4543af8207d31e0dd40a930cc343004afa62 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: Kyle Manna <kyle[at]kylemanna[d0t]com>
pkgname=backblaze-b2
_pkgname=b2
pkgver=4.0.3
pkgrel=3
pkgdesc='Backblaze B2 Command Line Client'
url='https://github.com/Backblaze/B2_Command_Line_Tool'
depends=('python'
'python-annotated-types>=0.5.0'
'python-argcomplete>=2'
'python-arrow>=1.0.2'
'python-b2sdk>=2.4.1'
'python-docutils>=0.19'
'python-class-registry>=4.0.5'
'python-rst2ansi=0.1.5'
'python-tabulate>=0.8.10'
'python-tqdm>=4.65.0'
'python-platformdirs>=3.11.0'
)
makedepends=('python-build'
'python-installer'
'python-pdm-backend'
'python-wheel'
)
# MIT or Creative Commons: https://www.backblaze.com/using_b2_code.html
license=('MIT')
arch=('any')
source=("https://github.com/Backblaze/B2_Command_Line_Tool/releases/download/v${pkgver}/${_pkgname}-${pkgver}.tar.gz")
sha256sums=('f4e3f1c82c9762f889bb2dd6690d4f3d1d5696888fe772bc986d475caf6186d2')
build() {
cd ${srcdir}/${_pkgname}-${pkgver}
python -m build --wheel --no-isolation
}
package() {
cd ${srcdir}/${_pkgname}-${pkgver}
python -m installer --destdir="$pkgdir" dist/*.whl
# uu-coreutils messes up the directory permissions (644, expect 755)
#install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
install -d "$pkgdir/usr/share/licenses/$pkgname"
install LICENSE "$pkgdir/usr/share/licenses/$pkgname"
# https://wiki.archlinux.org/index.php/Python_package_guidelines
local site_packages=$(python -c 'import site; print(site.getsitepackages()[0])')
rm -rf "${pkgdir}${site_packages}/test"
# Installed to backblaze-b2 because the Boost pkg installs /usr/bin/b2
mv ${pkgdir}/usr/bin/b2 ${pkgdir}/usr/bin/backblaze-b2
}
|