summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 5e044f898b8ed957271630e1b19fd3597da90906 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
# Maintainer: Mario Finelli <mario at finel dot li>

_pkgname=backblaze-b2
_reponame="B2_Command_Line_Tool"

pkgname="${_pkgname}-git"
pkgver=r257.a132718
pkgrel=1
pkgdesc="Backblaze B2 Command Line Client."
arch=('any')
url="https://www.backblaze.com/b2/cloud-storage.html"
license=('MIT')
depends=('python2')
makedepends=('git')
optdepends=('python-tqdm: upload/download progress bar')
provides=("$_pkgname")
conflicts=("$_pkgname")
source=("git://github.com/Backblaze/$_reponame.git")
md5sums=('SKIP')

pkgver() {
    cd "$srcdir/$_reponame"
    printf "r%s.%s" "$(git rev-list --count HEAD)" \
        "$(git rev-parse --short HEAD)"
}

build() {
    cd "$srcdir/$_reponame"
    python2 setup.py build
}

package() {
    cd "$srcdir/$_reponame"
    python2 setup.py install --root="$pkgdir" --optimize=1

    install -Dm0644 contrib/bash_completion/b2 \
        "$pkgdir/etc/bash_completion.d/b2"
    install -Dm0644 LICENSE "$pkgdir/usr/share/licenses/$_pkgname/LICENSE"
}