blob: a4fd705da83667099e85ed19191d04c26c722933 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: graysky <graysky AT archlinux DOT us>
# Contributor: germar <germar DOT reitze AT gmail DOT com>
pkgname=('backintime' 'backintime-cli')
_pkgname="backintime"
pkgver=1.2.0
pkgrel=1
arch=('any')
url="https://github.com/bit-team/backintime"
license=('GPL')
makedepends=('python')
#source=("https://github.com/bit-team/$_pkgname/archive/v$pkgver.tar.gz")
source=("$_pkgname-$pkgver.tar.gz::https://github.com/bit-team/$_pkgname/archive/v$pkgver.tar.gz")
sha256sums=('79eb77060df2471b0a3baacacab237cc4ee0d712d27e5b98c5398550e89d2115')
build() {
cd "$_pkgname-$pkgver/common"
./configure --python --no-fuse-group
make
cd "$srcdir/$_pkgname-$pkgver/qt"
./configure --python
make
}
test() {
cd "$_pkgname-$pkgver/common"
make test
}
package_backintime-cli() {
pkgdesc="Simple backup system inspired from the Flyback Project and TimeVault. CLI version."
depends=('cron' 'fuse2' 'openssh' 'python-dbus' 'python-keyring' 'rsync')
optdepends=('backintime: QT5 GUI version'
'encfs: encrypted filesystem in user-space'
'pm-utils: for laptops allows an option to not snapshot on battery'
'sshfs: FUSE client based on the ssh file transfer protocol')
cd "$_pkgname-$pkgver/common"
make DESTDIR="$pkgdir" install
}
package_backintime() {
pkgdesc="Simple backup system inspired from the Flyback Project and TimeVault. QT5 GUI version."
depends=("backintime-cli=$pkgver" 'libnotify' 'polkit' 'python-dbus' 'python-pyqt5' 'xorg-xdpyinfo')
# note users can optionally install EITHER kompare OR meld but not both!
optdepends=('kompare: diff/patch frontend'
'meld: diff/patch frontend'
'python-keyring: store and access passwords safely')
cd "$_pkgname-$pkgver/qt"
make DESTDIR="$pkgdir" install
}
# vim:set ts=8 sts=2 sw=2 et:
|