blob: 0d3e2de67fa01b2b085effa9d02e1f74ee1bed1c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Maintainer: graysky <graysky AT archlinux DOT us>
# Contributor: germar <germar DOT reitze AT gmail DOT com>
pkgname=('backintime' 'backintime-cli')
_pkgname="backintime"
pkgver=1.1.8
pkgrel=3
arch=('any')
url="https://launchpad.net/backintime"
license=('GPL')
makedepends=('python')
_stupidnumber=219057574
source=("https://launchpadlibrarian.net/$_stupidnumber/$_pkgname-$pkgver.tar.gz"
"Fix_bug_473-AttributeError.patch"
"https://launchpadlibrarian.net/$((_stupidnumber + 1))/$_pkgname-$pkgver.tar.gz.asc")
sha256sums=('a1f2d210e95633dfe383eb50b3b560d1e09c43de4ce89dd4cb193cab40cb8a1e'
'281b75fa6726e621b8ecabe8310b7e9e126848eb2215082df38fdf2cbdc52786'
'SKIP')
validpgpkeys=('3E70692EE3DB8BDDA5991C90615F366D944B4826') # Germar Reitze
# https://wiki.archlinux.org/index.php/Makepkg#Signature_checking
prepare() {
cd "$_pkgname-$pkgver/common"
patch -i "$srcdir/Fix_bug_473-AttributeError.patch"
}
build() {
cd "$_pkgname-$pkgver/common"
./configure --python --no-fuse-group
make
cd "$srcdir/$_pkgname-$pkgver/qt4"
./configure --python
make
}
package_backintime-cli() {
pkgdesc="Simple backup system inspired from the Flyback Project and TimeVault. CLI version."
depends=('rsync' 'cron' 'openssh' 'python-keyring' 'python-dbus' 'polkit')
optdepends=('backintime: QT4 GUI version'
'encfs: encrypted filesystem in user-space'
'pm-utils: for laptops allows an option to not snapshot on battery'
'sshfs: FUSE client based on the ssh file transfer protocol')
conflicts=('backintime<1.1.0')
replaces=('backintime<1.1.0')
cd "$_pkgname-$pkgver/common"
make DESTDIR="$pkgdir" install
}
package_backintime() {
pkgdesc="Simple backup system inspired from the Flyback Project and TimeVault. QT4 GUI version."
depends=("backintime-cli=$pkgver" 'xorg-xdpyinfo' 'python-pyqt4' 'libnotify'
'ttf-font' 'icu' 'polkit')
# note users can optionally install EITHER kompare OR meld but not both!
optdepends=('kompare: diff/patch frontend'
'meld: diff/patch frontend'
'python-keyring: store and access passwords safely')
conflicts=("backintime<1.1.0")
replaces=("backintime<1.1.0")
cd "$_pkgname-$pkgver/qt4"
make DESTDIR="$pkgdir" install
}
|