blob: 799771065cd314325e38cbf15d4f9459182e7a9a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: graysky <graysky AT archlinux DOT us>
# Contributor: germar <germar DOT reitze AT gmail DOT com>
pkgname=(backintime backintime-cli)
_pkgname="backintime"
pkgver=1.3.1
pkgrel=4
arch=(any)
url="https://github.com/bit-team/backintime"
license=(GPL)
makedepends=(python)
checkdepends=(openssh python-dbus rsync systemd)
source=("$_pkgname-$pkgver.tar.gz::https://github.com/bit-team/$_pkgname/archive/$pkgver.tar.gz"
0001-make-tools.py-work-on-python-3.10.patch::https://patch-diff.githubusercontent.com/raw/bit-team/backintime/pull/1174.patch)
b2sums=('b5bea6aad750ffe133d650af9b957500f857fabc9ab14e7e02abe2e7cc3bad806c609f76c5f553e764435b3ab5b5096d21c7329bd7497814f8a4ab23cb58f49f'
'060784876df4be67324b49452b6382e542ba22071483ae1594e738e0480395415c84207fce66374be859f477b7e53f80fd8e0ef9ed93f1495b31b56f2387e52d')
prepare() {
cd "$_pkgname-$pkgver"
patch -Np1 -i ../0001-make-tools.py-work-on-python-3.10.patch
}
build() {
cd "$_pkgname-$pkgver/common"
./configure --python --no-fuse-group
make
cd "$srcdir/$_pkgname-$pkgver/qt"
./configure --python
make
}
check() {
cd "$_pkgname-$pkgver/common"
make test
}
package_backintime-cli() {
pkgdesc="Simple backup system inspired from the Flyback Project and TimeVault. CLI version."
depends=('cron' 'fuse2' 'openssh' 'python-dbus' 'python-keyring' 'rsync')
optdepends=('backintime: QT5 GUI version'
'encfs: encrypted filesystem in user-space'
'pm-utils: for laptops allows an option to not snapshot on battery'
'sshfs: FUSE client based on the ssh file transfer protocol')
cd "$_pkgname-$pkgver/common"
make DESTDIR="$pkgdir" install
}
package_backintime() {
pkgdesc="Simple backup system inspired from the Flyback Project and TimeVault. QT5 GUI version."
depends=("backintime-cli=$pkgver" 'libnotify' 'polkit' 'python-dbus' 'python-pyqt5' 'xorg-xdpyinfo')
# note users can optionally install EITHER kompare OR meld but not both!
optdepends=('kompare: diff/patch frontend'
'meld: diff/patch frontend'
'python-keyring: store and access passwords safely')
cd "$_pkgname-$pkgver/qt"
make DESTDIR="$pkgdir" install
}
# vim:set ts=8 sts=2 sw=2 et:
|