blob: d1ecee0c2793f8bd4412e870235611e5b69daa82 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: willemw <willemw12@gmail.com>
_pkgname=backintime
pkgname=($_pkgname-git $_pkgname-cli-git)
pkgver=1.4.3.r18.g61e4a4b0
pkgrel=1
url=https://github.com/bit-team/backintime
license=(GPL)
arch=(any)
makedepends=(git openssh python-dbus python-keyring rsync systemd xorg-xdpyinfo)
checkdepends=(python-pyfakefs python-pylint python-pyqt6)
source=($_pkgname::git+$url.git)
sha256sums=('SKIP')
pkgver() {
git -C $_pkgname describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "$srcdir/$_pkgname/common"
./configure --python3 --no-fuse-group
make
cd "$srcdir/$_pkgname/qt"
./configure --python3
make
}
check() {
# Isolate some tests, accessing files in ~/.ssh/, etc.
HOME=$srcdir/tmp
export XDG_CACHE_HOME=$HOME/.cache
mkdir -p $XDG_CACHE_HOME
make -C $_pkgname/common test
rm -rf $_pkgname/common/tmp
}
package_backintime-cli-git() {
pkgdesc='Simple backup/snapshot system inspired by Flyback and TimeVault. CLI version.'
depends=(cron fuse2 openssh python-dbus python-keyring python-packaging rsync)
#'ecryptfs-utils: verify home encryption'
optdepends=('encfs: encrypted filesystems'
'sshfs: remote filesystems')
provides=($_pkgname-cli)
conflicts=($_pkgname-cli)
make -C $_pkgname/common DESTDIR="$pkgdir" install
}
package_backintime-git() {
pkgdesc='Simple backup/snapshot system inspired by Flyback and TimeVault. Qt6 GUI version.'
#depends=(backintime-cli libnotify polkit python-dbus python-pyqt6 xorg-xdpyinfo)
depends=(backintime-cli-git libnotify polkit python-dbus python-pyqt6 xorg-xdpyinfo)
optdepends=('kompare: diff tool'
'meld: diff tool'
'python-secretstorage: store passwords')
provides=($_pkgname)
conflicts=($_pkgname)
make -C $_pkgname/qt DESTDIR="$pkgdir" install
}
|