PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

# Maintainer: detiam <dehe_tian@outlook.com>

pkgname=balena-etcher-electron-bin
pkgver=1.18.8
pkgrel=1
pkgdesc="Flash OS images to SD cards & USB drives, safely and easily (use system electron runtime)"
arch=(x86_64)
url="https://www.balena.io/etcher"
license=("Apache License 2.0")
provides=("balena-etcher-appimage=${pkgver}")
conflicts=('balena-etcher-appimage' 'balena-etcher')
depends=(
  "electron>=19"
  "electron<20"
  gconf
  gtk3
  nss
  libxss
  libxtst
  xdg-utils
  at-spi2-core
  util-linux-libs
  libsecret
  alsa-lib
  glib2
  polkit
  libusb
)
optdepends=('libappindicator-gtk3' 'libnotify: for notifications')
makedepends=('fuse2')
options=(!strip)
source=(
    "https://github.com/balena-io/etcher/releases/download/v${pkgver}/balenaEtcher-${pkgver}-x64.AppImage"
    "balena-etcher-electron.sh"
)
sha256sums=('2028eb86e04d32396dbf25ef3a68a2adad44eec74a33690d7514a6828a5ec498'
            '553d29f91b6e9fd65e8c7af0b100fa17d4ed299045f5196b2ef23795e99e1c77')
_image="$(basename "${source[0]}")"

prepare() {
    cd "${srcdir}"
    chmod +x "${_image}"
    ./"${_image}" --appimage-extract
    sed -i 's/Exec=.*/Exec=\/usr\/bin\/balena-etcher-electron %U/' "${srcdir}/squashfs-root/balena-etcher.desktop"
}

package() {
  install -Dm755 "${srcdir}/balena-etcher-electron.sh" "${pkgdir}/usr/bin/balena-etcher-electron"
  install -dm755 "${pkgdir}/usr/lib/"
  install -dm755 "${pkgdir}/usr/share/"
  cp -r --no-preserve=mode,ownership "${srcdir}/squashfs-root/usr/share/icons" "${pkgdir}/usr/share/"
  cp -r --no-preserve=mode,ownership "${srcdir}/squashfs-root/resources/app" "${pkgdir}/usr/lib/balena-etcher-electron"
  install -Dm644 "${srcdir}/squashfs-root/balena-etcher.desktop" "${pkgdir}/usr/share/applications/balena-etcher.desktop"
}