PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=bash-completion-git
pkgver=2.17.0.r105.gbc5dffff
pkgrel=1
pkgdesc="Programmable completion functions for bash"
arch=('any')
url="https://github.com/scop/bash-completion"
license=('GPL-2.0-or-later')
depends=('bash')
makedepends=('git')
provides=("bash-completion=$pkgver")
conflicts=('bash-completion')
options=(!emptydirs)
source=("git+https://github.com/scop/bash-completion.git")
sha256sums=('SKIP')


pkgver() {
  cd "bash-completion"

  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "bash-completion"

  autoreconf -fi
  ./configure \
    --prefix="/usr" \
    --sysconfdir="/etc"
  make
}

package() {
  cd "bash-completion"

  make DESTDIR="$pkgdir" install

  # bash-completion is sourced in /etc/bash.bashrc so that non-bash shell don't source it
  rm "$pkgdir/etc/profile.d/bash_completion.sh"

  # checksec 3.1.0-2 ships its own
  rm "$pkgdir/usr/share/bash-completion/completions-core/checksec.bash"

  # patchutils 0.4.4-1 ships its own
  rm "$pkgdir/usr/share/bash-completion/completions-fallback/interdiff.bash"

  # remove Slackware's makepkg completion
  rm "$pkgdir/usr/share/bash-completion/completions-core/makepkg.bash"
}