summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: ad71c0a1d42dfb033dc02643196725f7651120fc (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
# Maintainer: Jens Adam <jra@byte.cx>

pkgname=bastet
pkgver=0.43.2
pkgrel=1
pkgdesc="Tetris(r) clone with 'bastard' block-choosing AI"
url="http://fph.altervista.org/prog/bastet.html"
license=('GPL3')
arch=('i686' 'x86_64')
depends=('boost-libs' 'ncurses')
makedepends=('boost')
backup=('var/games/bastet.scores2')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/fph/bastet/archive/${pkgver}.tar.gz")
md5sums=('aee009b77b8cf9516d686bd24673800e')

build() {
  cd "${srcdir}"/${pkgname}-${pkgver}
  make
}

package() {
  cd "${srcdir}"/${pkgname}-${pkgver}

  # populate files
  install -D bastet "${pkgdir}"/usr/bin/bastet
  install -D -m 0644 bastet.6 "${pkgdir}"/usr/share/man/man6/bastet.6
  install -D -m 0644 bastet.png "${pkgdir}"/usr/share/pixmaps/bastet.png
  install -D -m 0644 bastet.desktop "${pkgdir}"/usr/share/applications/bastet.desktop
  install -D -m 0644 bastet.appdata.xml "${pkgdir}"/usr/share/appdata/bastet.appdata.xml
  for F in AUTHORS INSTALL NEWS README; do
    install -D -m 0644 ${F} "${pkgdir}"/usr/share/doc/bastet/${F}
  done

  # prepare the (optional) global highscore file
  # (users need to be in 'games' group, obviously)
  install -d -m 0775 -g games "${pkgdir}"/var/games
  touch "${pkgdir}"/var/games/bastet.scores2
  chmod 0664 "${pkgdir}"/var/games/bastet.scores2
  chown root:games "${pkgdir}"/var/games/bastet.scores2
}