summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: f6d12fc3b58ad7c6f19cf912be1eaab504fcb803 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
# Maintainer: xotkot
pkgname=batorrent-git
pkgver=4.8.0.beta2.r0.g66a60ff
pkgrel=2
pkgdesc='A modern, open-source BitTorrent client focused on privacy, performance, and clarity. No ads, no telemetry.'
arch=(x86_64)
url='https://github.com/Mateuscruz19/BATorrent'
license=(MIT)
conflicts=(batorrent)
provides=(batorrent)
depends=(
  libtorrent-rasterbar
  qt6-svg
  qt6-base
  qt6-multimedia
  qt6-declarative
  qtkeychain-qt6
  openssl
  libstdc++
  glibc
  libgcc
)
makedepends=(
  git
  cmake
  boost
)
source=("$pkgname::git+$url")
b2sums=(SKIP)

pkgver() {
  cd "$pkgname"
  git describe --tags --long --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "$pkgname"
  cmake -B build -DCMAKE_BUILD_TYPE=Release
  cmake --build build -j
}

package() {
  cd "$pkgname"
  
  install -Dm0755 "$srcdir/$pkgname/build/BATorrent"        "$pkgdir/usr/bin/BATorrent"
  install -Dm0644 "$srcdir/$pkgname/LICENSE"                "$pkgdir/usr/share/licenses/BATorrent/LICENSE"
  install -Dm0644 "$srcdir/$pkgname/src/images/logo.svg"    "$pkgdir/usr/share/pixmaps/batorrent.svg"
  install -Dm0644 "$srcdir/$pkgname/src/images/logo1.png"   "$pkgdir/usr/share/pixmaps/batorrent.png"
  install -Dm0644 "$srcdir/$pkgname/dist/batorrent.desktop" "$pkgdir/usr/share/applications/batorrent.desktop"
}