blob: 15224bea61eb0cc25b5d885de4c7fa0543d6bb8a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Andre Schröder <andre.schroedr at gmail dot com>
# All my PKGBUILDs are managed at https://github.com/schra/pkgbuilds
_name=bats-core
pkgname=$_name-git
pkgver=v1.2.1.r16.gda118fd
_mainfolder=$_name
pkgrel=1
pkgdesc='Bash Automated Testing System'
arch=(any)
url=https://github.com/bats-core/bats-core
license=(MIT)
depends=(bash)
makedepends=(git)
source=("git+$url")
sha256sums=('SKIP')
conflicts=(bash-bats)
provides=(bash-bats)
pkgver() {
cd "$srcdir/$_mainfolder"
# from https://wiki.archlinux.org/index.php/VCS_package_guidelines#Git
( set -o pipefail
git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
)
}
check() {
cd "$srcdir/$_mainfolder"
bin/bats --tap test
}
package() {
cd "$srcdir/$_mainfolder"
# In Arch Linux the correct path is /usr/lib and not /usr/libexec, see
# https://wiki.archlinux.org/index.php/Arch_package_guidelines#Package_etiquette
#
# Also rename the bats-core/ folder to bats/
sed -i 's/BATS_ROOT\/libexec\/bats-core\/bats/BATS_ROOT\/lib\/bats\/bats/g' bin/bats
# Rename the bats-core/ folder to bats/
sed -i 's/BATS_ROOT\/lib\/bats-core\//BATS_ROOT\/lib\/bats\//g' libexec/bats-core/*
install -dm755 "$pkgdir"/{usr/bin,usr/lib/bats,usr/share/man/man{1,7},usr/share/licenses/$_name}
install -m 755 "bin"/* "$pkgdir/usr/bin"
install -m 755 "lib/bats-core"/* "$pkgdir/usr/lib/bats"
install -m 755 "libexec/bats-core"/* "$pkgdir/usr/lib/bats"
install -m 644 "man/bats.1" "$pkgdir/usr/share/man/man1"
install -m 644 "man/bats.7" "$pkgdir/usr/share/man/man7"
install -m 644 LICENSE.md "$pkgdir"/usr/share/licenses/$_name/LICENSE.md
}
|