blob: e4652d4fb55b44ae4b3316a05220bf58eb36421a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: dragoneki <dragoneki at proton dot me>
pkgname=bazaar-git
_pkgname=bazaar
pkgver=0.7.15.r71.g307770f
pkgrel=1
pkgdesc="A new app store for GNOME with focus on flatpaks, particularly Flathub. (git version)"
arch=('x86_64')
url="https://github.com/kolunmi/bazaar"
license=('GPL-3.0-only')
depends=(
'appstream'
'cairo'
'dconf'
'flatpak'
'glib2'
'glycin'
'glycin-gtk4'
'graphene'
'gtk4'
'gtksourceview5'
'json-glib'
'libadwaita'
'libdex'
'libheif'
'libmalcontent'
'libproxy'
'libsecret'
'libsoup3'
'libxmlb'
'libyaml'
'md4c'
'pango'
'webkitgtk-6.0'
)
makedepends=('blueprint-compiler' 'git' 'glib2-devel' 'meson' 'python-babel' 'ninja')
optdepends=('krunner-bazaar: krunner integration' 'malcontent: parental controls')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
source=(
"bazaar::git+https://github.com/kolunmi/bazaar.git"
)
sha256sums=('SKIP')
pkgver() {
cd "${_pkgname}"
git describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
meson setup "${_pkgname}" build --prefix=/usr --buildtype=release
meson compile -C build
}
package() {
meson install -C build --destdir "${pkgdir}"
}
|