blob: ec04c525e7cff54b7d34bd3d25b2dfaa4da9f91d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Donald Webster <fryfrog@gmail.com>
# Contributor: Pieter Goetschalckx <3.14.e.ter <at> gmail <dot> com>
pkgname=bazarr
pkgver=1.4.2
pkgrel=1
pkgdesc="Subtitle management and download automation for Sonarr and Radarr."
arch=('any')
url="https://github.com/morpheus65535/bazarr"
license=('GPL3')
options=('!strip' 'staticlibs')
makedepends=(
'unzip'
'python-setuptools'
)
depends=(
'sqlite'
'python'
'python-gevent'
'python-gevent-websocket'
'python-lxml'
'python-numpy'
'python-pillow'
'python-webrtcvad'
'ffmpeg'
'unrar'
)
source=(
"bazarr-${pkgver}.zip::https://github.com/morpheus65535/bazarr/releases/download/v${pkgver}/bazarr.zip"
'bazarr.service'
'bazarr.sysusers'
'bazarr.install'
'bazarr.tmpfiles'
)
noextract=("bazarr-${pkgver}.zip")
sha256sums=('d4ea9b0b2426037dd9bf2084d75652c95c04832ca6d18d045faab1de0ef59674'
'a6f6a045e8a5d3ce6185148ee7b0b9fd323b6480ae284f6ceead4ca71e6fd109'
'92fd48cbd7e5fe3a0388bbe756a52098fc461ef2dc87d9e886452e4f15acdcdc'
'573beeac951d427e980332ce4d8645ae2299082e6c9c04f96e2a41a98c3acc60'
'e7055260d0f3554e8b628d9560d8e12a40f720d76542048df0dfc838db88357b')
prepare() {
unzip -qq -o -d bazarr-${pkgver} bazarr-${pkgver}.zip
}
package() {
install -d -m 755 "${pkgdir}/usr/lib/bazarr"
cp -dpr --no-preserve=ownership "${srcdir}/bazarr-${pkgver}/"* "${pkgdir}/usr/lib/bazarr"
install -D -m 644 "${srcdir}/bazarr.service" "${pkgdir}/usr/lib/systemd/system/bazarr.service"
install -D -m 644 "${srcdir}/bazarr.sysusers" "${pkgdir}/usr/lib/sysusers.d/bazarr.conf"
install -D -m 644 "${srcdir}/bazarr.tmpfiles" "${pkgdir}/usr/lib/tmpfiles.d/bazarr.conf"
}
|