blob: 445b8a7d0d37545a41ae9d08abaa83ff716fc5ed (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: zzjzxq33 <wojiushixxx at 126 dot com>
# Co-Maintainer: Misaka13514 <Misaka13514 at gmail dot com>
pkgname=bbg
pkgver=20240104
pkgrel=1
pkgdesc="A static blog generator built with electron"
arch=('any')
url="https://github.com/bbg-contributors/bbg"
license=('Unlicense')
depends=('electron')
conflicts=("${pkgname}-git")
source=(
'icon.png'::'https://github.com/bbg-contributors/bbg-resources/raw/753cf6fef826616425d32d51fa64541869fcf12c/icon.png'
"app-${pkgver}.asar"::"${url}/releases/download/${pkgver}/app.asar"
)
sha256sums=('f25a9595d339f61193a7e79c08c5f56014fa487a6ddee271d0785bb1cae2155f'
'715aeca035d5b18485e673f24544d78f93662e5918a37dd74f37afbf8dedea50')
package() {
cd "$srcdir"
install -Dm644 "app-${pkgver}.asar" "${pkgdir}/usr/lib/${pkgname}/app.asar"
install -Dm644 "icon.png" "${pkgdir}/usr/share/icons/${pkgname}.png"
install -Dm755 "/dev/stdin" "${pkgdir}/usr/bin/${pkgname}" << "EOF"
#!/bin/sh
exec electron /usr/lib/bbg/app.asar "$@"
EOF
install -Dm644 "/dev/stdin" "${pkgdir}/usr/share/applications/${pkgname}.desktop" << "EOF"
[Desktop Entry]
Name=bbg
Comment=blog generator
Keywords=
Exec=/usr/bin/bbg
TryExec=
Terminal=false
Icon=/usr/share/icons/bbg.png
Type=Application
StartupNotify=false
Categories=Office
EOF
}
|