blob: 424f0c3b2be8f1fa789d7ec48138730df684760b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# Maintainer: zzjzxq33 <wojiushixxx at 126 dot com>
# Co-Maintainer: Misaka13514 <Misaka13514 at gmail dot com>
pkgname=bbg
pkgver=20220522
pkgrel=1
pkgdesc="A static blog generator built with electron"
arch=('any')
url="https://github.com/baiyang-lzy/bbg"
license=('Unlicense')
depends=('electron16')
conflicts=("${pkgname}-git")
source=(
'bbg.sh'
'icon.png'::'https://github.com/baiyang-lzy/bbg-resources/raw/30dfd1cbdfbed040a74f05b0312302f3bf0c1c85/icon.png'
'bbg.desktop'
"app-${pkgver}.asar"::"${url}/releases/download/${pkgver}/app.asar"
)
sha256sums=(
'ef39a1c67ffe2228d8bb51256a5a666d8ecbbfbc935c1f515a6c087ba5fbe924'
'd5f8f191d914a140ab11999a176b226523dd78e6865a75b483013846503a5228'
'f503d93639c1f4d4e050eceb11adf64d369908e5941cfdbda3af30b2f3c73d96'
'04089ec7bd1b792c372c4eece86d7bd8048708593044fa6e6c75f99e0b030fa3'
)
package() {
cd "$srcdir"
install -dm755 "${pkgdir}/usr/share/${pkgname}"
install -Dm755 "bbg.sh" "${pkgdir}/usr/bin/${pkgname}"
install -Dm644 "app-${pkgver}.asar" "${pkgdir}/usr/share/${pkgname}/app.asar"
install -Dm644 "bbg.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
install -Dm644 "icon.png" "${pkgdir}/usr/share/icons/${pkgname}.png"
# install bbgvertype: https://github.com/baiyang-lzy/bbg/blob/f3d61ce4d79680329bad4cb014c909fb86037f38/App/start.js
echo "aur-bbg-zzjzxq33-misaka13514" | install -Dm644 /dev/stdin "${pkgdir}/usr/share/bbg/bbgvertype"
}
|