blob: 80ed7c2d54d1dcaad61597b10b5c691578ee520c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Maintainer: Gavin D. Howard <yzena.tech@gmail.com>
# Contributor: Klaus Alexander Seistrup <klaus@seistrup.dk>
# -*- mode: sh -*-
pkgname=bc-gh
pkgver=6.4.0
pkgrel=1
pkgdesc="Implementation of dc and POSIX bc with GNU extensions"
arch=('i686' 'x86_64' 'arm' 'armv6h' 'armv7h' 'aarch64')
url="https://github.com/gavinhoward/bc"
license=('BSD')
provides=('bc')
conflicts=('bc')
depends=('libedit')
options=('lto')
source=(
"$pkgname-$pkgver.tar.xz::$url/releases/download/$pkgver/bc-$pkgver.tar.xz"
"$pkgname-$pkgver.tar.xz.sig::$url/releases/download/$pkgver/bc-$pkgver.tar.xz.sig"
)
sha512sums=(
'6c7a86c534214e765e3890dffe77fb85ddf0764cde0c6ceb0385cce7de4c0d2db0815faf6bcf161fad75591461c346811a61c42c5eced7c3d84fe5b7eb719b60'
'f0b6519c7d61d9be01c5643c1df0262a05772c38158eb0974bb98d04f6ef6072be427b7696b489dd6992cbc671b94bcd5159f8bee3cc85106d3bde7e12cd613d'
)
sha256sums=(
'614f59ce6b155a2f7d637112fa71156d890887967e63b97eccaa6a50b01ffbd4'
'cc7b36e2c53102ee6ed7957585f05b1bf61335e100c0ffb46cf715f8286e7ce6'
)
validpgpkeys=('FF360647C7A7147F27DAAEC1B132F881C306590A')
build() {
cd "bc-$pkgver"
test -n "$LTOFLAGS" || LTOFLAGS='-flto=auto'
CFLAGS="$CFLAGS -O3"
PREFIX=/usr ./configure.sh -p GNU -e -G -sbc.banner -sdc.tty_mode
make
}
check() {
cd "bc-$pkgver"
env LANG=C LC_ALL=C make check
}
package() {
cd "bc-$pkgver"
DESTDIR="$pkgdir" make install
install -Dm0644 LICENSE.md "$pkgdir/usr/share/licenses/$pkgname/LICENSE.md"
for _doc in {NEWS,NOTICE,README}.md; do
install -Dm0644 "$_doc" "$pkgdir/usr/share/doc/$pkgname/$_doc"
done
}
# eof
|