blob: 50d03d5f838e57126c2d11113a895c5541602b5e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Maintainer: Gavin D. Howard <yzena.tech@gmail.com>
# Contributor: Klaus Alexander Seistrup <klaus@seistrup.dk>
# -*- mode: sh -*-
pkgname=bc-gh
pkgver=6.2.5
pkgrel=1
pkgdesc="Implementation of dc and POSIX bc with GNU extensions"
arch=('i686' 'x86_64' 'arm' 'armv6h' 'armv7h' 'aarch64')
url="https://github.com/gavinhoward/bc"
license=('BSD')
provides=('bc')
conflicts=('bc')
depends=('libedit')
options=('lto')
source=(
"$pkgname-$pkgver.tar.xz::$url/releases/download/$pkgver/bc-$pkgver.tar.xz"
"$pkgname-$pkgver.tar.xz.sig::$url/releases/download/$pkgver/bc-$pkgver.tar.xz.sig"
)
sha512sums=(
'982bfde03c5f6167fe7a4aa5daf1c418cb80637eb9052dd55cda7e575e6835bd03fa3c946e581312e38dfba23f60d48bf459974f212c3a647eaf1991aaef5b06'
'1a04139984ec62e3be0fb831502d2201b39fb0d524e96bc9d36c6fa62df880a42a0da40d7b51962366c46f8ecc9a1a5d043e5e502773d7dbe7bf00749ea0f4e0'
)
sha256sums=(
'25726082458d37a7a0ce1d5ffe37f5028d59e4f6e9742d280a828fed3dfb9fb0'
'1814fc5cd9eb859d0ae7de032564ebb85745f0cd245736ad55f8d232b1aa831d'
)
validpgpkeys=('FF360647C7A7147F27DAAEC1B132F881C306590A')
build() {
cd "bc-$pkgver"
test -n "$LTOFLAGS" || LTOFLAGS='-flto=auto'
CFLAGS="$CFLAGS -O3"
PREFIX=/usr ./configure.sh -p GNU -e -G -sbc.banner -sdc.tty_mode
make
}
check() {
cd "bc-$pkgver"
env LANG=C LC_ALL=C make check
}
package() {
cd "bc-$pkgver"
DESTDIR="$pkgdir" make install
install -Dm0644 LICENSE.md "$pkgdir/usr/share/licenses/$pkgname/LICENSE.md"
for _doc in {NEWS,NOTICE,README}.md; do
install -Dm0644 "$_doc" "$pkgdir/usr/share/doc/$pkgname/$_doc"
done
}
# eof
|