blob: 686629fb4e081f51bc4a7ce525d08911693cd9d7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Maintainer: Gavin D. Howard <yzena.tech@gmail.com>
# Contributor: Klaus Alexander Seistrup <klaus@seistrup.dk>
# -*- mode: sh -*-
pkgname=bc-gh
pkgver=6.2.4
pkgrel=1
pkgdesc="Implementation of dc and POSIX bc with GNU extensions"
arch=('i686' 'x86_64' 'arm' 'armv6h' 'armv7h' 'aarch64')
url="https://github.com/gavinhoward/bc"
license=('BSD')
provides=('bc')
conflicts=('bc')
depends=('libedit')
options=('lto')
source=(
"$pkgname-$pkgver.tar.xz::$url/releases/download/$pkgver/bc-$pkgver.tar.xz"
"$pkgname-$pkgver.tar.xz.sig::$url/releases/download/$pkgver/bc-$pkgver.tar.xz.sig"
)
sha512sums=(
'0d573b118214aa345995f28ccce16dbbeb8dbb3aa793414b5e6c4a693f5f51e3c54f3fda60703b66183476933363d21dd2de06cec8bbc54d1bce4725957e5d38'
'd6c718f8308a42b7007cdc3f13e32f76681728b58673d9f178f107f57df9eb1c5d26e706974f981e39e3cdba60081f11133d3074172a301fa4b0401df26bdc2b'
)
sha256sums=(
'2b9f712e1e02473ca0e01979dd026e818dafc169a3cf63887d91bdaafeb812b5'
'8cdf65daacd62ad1753396268fc5a29aa82d0800cb120bedb73db6e1778fa0ea'
)
validpgpkeys=('FF360647C7A7147F27DAAEC1B132F881C306590A')
build() {
cd "bc-$pkgver"
test -n "$LTOFLAGS" || LTOFLAGS='-flto=auto'
CFLAGS="$CFLAGS -O3"
PREFIX=/usr ./configure.sh -p GNU -e -G -sbc.banner -sdc.tty_mode
make
}
check() {
cd "bc-$pkgver"
env LANG=C LC_ALL=C make check
}
package() {
cd "bc-$pkgver"
DESTDIR="$pkgdir" make install
install -Dm0644 LICENSE.md "$pkgdir/usr/share/licenses/$pkgname/LICENSE.md"
for _doc in {NEWS,NOTICE,README}.md; do
install -Dm0644 "$_doc" "$pkgdir/usr/share/doc/$pkgname/$_doc"
done
}
# eof
|