blob: 3963ec4712398e123e6dd91a47f0ff246953fce6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: Gavin D. Howard <yzena.tech@gmail.com>
# Contributor: Klaus Alexander Seistrup <klaus@seistrup.dk>
# -*- mode: sh -*-
pkgname=bc-gh
pkgver=6.2.2
pkgrel=1
pkgdesc="Implementation of dc and POSIX bc with GNU extensions"
arch=('i686' 'x86_64' 'arm' 'armv6h' 'armv7h' 'aarch64')
url="https://github.com/gavinhoward/bc"
license=('BSD')
provides=('bc')
conflicts=('bc')
depends=('libedit')
options=('lto')
source=(
"$pkgname-$pkgver.tar.xz::$url/releases/download/$pkgver/bc-$pkgver.tar.xz"
"$pkgname-$pkgver.tar.xz.sig::$url/releases/download/$pkgver/bc-$pkgver.tar.xz.sig"
)
sha512sums=(
'11389ebd522dddb4b255856452d4ff851915331e36682899e946a3eee46e6a3b7ac7d28a0be8b86fc79c230f8ea3d8f335a4722a0c49daa68c51b6c667e1d1fe'
'ff5610cd0b33019277d1df84e9d7fcef7ab2c260099a7a02349a2ac3324c8b6be72f1dfb08a51818d8d8739394010a945bb7cf1e85bbc6fec856958157e7f071'
)
sha256sums=(
'5b6fe23b720ab898c9c9c9cbdc83e124791b0b575005ec91a63175d3b69b90f2'
'f692fe8e6ee7a8bca8527f7cdad653e82b16e398cc0d201a3aaa65116839cfd7'
)
validpgpkeys=('FF360647C7A7147F27DAAEC1B132F881C306590A')
build() {
cd "bc-$pkgver"
CFLAGS="$CFLAGS -O3"
PREFIX=/usr ./configure.sh -p GNU -e -G -sbc.banner -sdc.tty_mode
make
}
check() {
cd "bc-$pkgver"
env LANG=C LC_ALL=C make check
}
package() {
cd "bc-$pkgver"
DESTDIR="$pkgdir" make install
install -Dm0644 LICENSE.md "$pkgdir/usr/share/licenses/$pkgname/LICENSE.md"
for _doc in {NEWS,NOTICE,README}.md; do
install -Dm0644 "$_doc" "$pkgdir/usr/share/doc/$pkgname/$_doc"
done
}
# eof
|