blob: 41ef9ebe67780f7b5749aafbc241a5340a352b31 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Maintainer: Gavin D. Howard <yzena.tech@gmail.com>
# Contributor: Klaus Alexander Seistrup <klaus@seistrup.dk>
# -*- mode: sh -*-
pkgname=bc-gh
pkgver=6.3.0
pkgrel=1
pkgdesc="Implementation of dc and POSIX bc with GNU extensions"
arch=('i686' 'x86_64' 'arm' 'armv6h' 'armv7h' 'aarch64')
url="https://github.com/gavinhoward/bc"
license=('BSD')
provides=('bc')
conflicts=('bc')
depends=('libedit')
options=('lto')
source=(
"$pkgname-$pkgver.tar.xz::$url/releases/download/$pkgver/bc-$pkgver.tar.xz"
"$pkgname-$pkgver.tar.xz.sig::$url/releases/download/$pkgver/bc-$pkgver.tar.xz.sig"
)
sha512sums=(
'8b66239fb8ee212f9d4b0b2d5649b522101d9bf8c838ffe2e44347c222260a335fd274fef70163dad39d8aef5b3ffa6182c49d498e1982004e4ecb2bae6e2dc2'
'055b3dc6a1410b2a84450aa166b1ca2d2718b5ab5e354d59ea00d2006605900be833cdc8afc093114c7142e351a46361f934dfa931fa703e2b04d9a569ff24aa'
)
sha256sums=(
'b1f484f48ff6d9fda2728be1066ce7efe28887e313207b60e18b27c7f41337af'
'daaa870cc7861c65fbeca0ff9a93b8602b21c14074364f775b47bcb6e071a417'
)
validpgpkeys=('FF360647C7A7147F27DAAEC1B132F881C306590A')
build() {
cd "bc-$pkgver"
test -n "$LTOFLAGS" || LTOFLAGS='-flto=auto'
CFLAGS="$CFLAGS -O3"
PREFIX=/usr ./configure.sh -p GNU -e -G -sbc.banner -sdc.tty_mode
make
}
check() {
cd "bc-$pkgver"
env LANG=C LC_ALL=C make check
}
package() {
cd "bc-$pkgver"
DESTDIR="$pkgdir" make install
install -Dm0644 LICENSE.md "$pkgdir/usr/share/licenses/$pkgname/LICENSE.md"
for _doc in {NEWS,NOTICE,README}.md; do
install -Dm0644 "$_doc" "$pkgdir/usr/share/doc/$pkgname/$_doc"
done
}
# eof
|