blob: 91ddf37e17588876571ee0ccf81bf0bfa6927e4b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Maël Kerbiriou <m431.kerbiriou@gmail.com>
pkgname=bcalm-git
_pkgname=bcalm
pkgver=2.2.0.r49.g890ea4a
pkgrel=1
pkgdesc="constructs compacted de Bruijn graph from sequencing data"
arch=('i686' 'x86_64')
url="https://github.com/GATB/bcalm"
license=('custom')
conflicts=("$_pkgname")
provides=("$_pkgname")
depends=('python')
makedepends=('cmake')
source=("git+https://github.com/GATB/bcalm.git"
"git+https://github.com/GATB/gatb-core.git")
md5sums=('SKIP' 'SKIP')
prepare() {
cd "$_pkgname"
git submodule init
git config submodule.gatb-core.url "$srcdir/gatb-core"
git submodule update
}
pkgver() {
cd "$_pkgname"
git describe --long | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
builddir="$srcdir/$_pkgname/build"
mkdir -p "$builddir"
cd "$builddir"
cmake .. -DCMAKE_BUILD_TYPE=Release -DCMAKE_INTERPROCEDURAL_OPTIMIZATION=True
make
}
package() {
cd "$srcdir/$_pkgname"
install -Dm755 build/bcalm "$pkgdir/usr/bin/bcalm"
install -Dm755 scripts/convertToGFA.py "$pkgdir/usr/bin/bcalm_convertToGFA"
install -Dm755 scripts/pufferize.py "$pkgdir/usr/bin/bcalm_pufferize"
install -D -m644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|