blob: 83a050622cf4710fa19f58b712a75bab85cf31ff (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
|
# Maintainer: Omar Sandoval <osandov@osandov.com>
# Contributor: Troy Engel <troyengel+arch@gmail.com>
# Contributor: Manuel Mendez <mmendez534@gmail.com>
pkgbase=bcc-git
pkgname=('bcc-git' 'bcc-tools-git' 'python-bcc-git' 'python2-bcc-git')
pkgver=v0.5.0.r305.7c27c271
pkgrel=1
pkgdesc='BPF Compiler Collection - latest git code'
arch=('x86_64')
url='https://github.com/iovisor/bcc'
license=('Apache')
conflicts=('bcc')
makedepends=('cmake' 'clang>=3.7.0' 'llvm>=3.7.0' 'flex' 'bison' 'python' 'python2')
checkdepends=('netperf' 'iperf')
source=('bcc-git::git+https://github.com/iovisor/bcc')
sha256sums=('SKIP')
pkgver() {
cd "${srcdir}/${pkgbase}"
printf "%s" "$(git describe --long | sed 's/\([^-]*-\)g/r\1/;s/-/./g')"
}
build() {
cd "${srcdir}/${pkgbase}"
rm -rf build
mkdir build
cd build
# The python version is irrelevant at this stage
cmake -DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_INSTALL_LIBDIR=/usr/lib ..
make
}
package_bcc-git() {
pkgdesc='BPF Compiler Collection - C library and examples - latest git code'
depends=('linux-headers')
optdepends=('bcc-tools-git: Python utilites using the BCC library'
'python-bcc-git: Python 3 bindings for BCC'
'python2-bcc-git: Python 2 bindings for BCC')
makedepends=('cmake' 'clang>=3.7.0' 'llvm>=3.7.0' 'flex' 'bison')
provides=('bcc-git' 'libbcc-git')
cd "${srcdir}/${pkgbase}/build"
# Install the kitchen sink
make DESTDIR="${pkgdir}" install
# These go in a split package python*-bcc-git
rm -rf "${pkgdir}"/usr/lib/python*
# These go in a split package bcc-tools-git
rm -rf "${pkgdir}"/usr/share/bcc/{tools,man}
}
package_bcc-tools-git() {
pkgdesc='BPF Compiler Collection - Tools - latest git code'
arch=('any')
depends=('bcc-git')
conflicts=('bcc-tools')
optdepends=('python-bcc-git: Python 3 bindings for BCC'
'python2-bcc-git: Python 2 bindings for BCC')
cd "${srcdir}/${pkgbase}/build/tools"
make DESTDIR="${pkgdir}" install
cd "${srcdir}/${pkgbase}/build/man"
make DESTDIR="${pkgdir}" install
}
package_python-bcc-git() {
pkgdesc='BPF Compiler Collection - Python 3 bindings - latest git code'
arch=('any')
depends=('bcc-git' 'python')
makedepends=('cmake')
cd "${srcdir}/${pkgbase}/build"
# Force a quick python3 binding build (C library is already buidl)
cmake -DREVISION="${pkgver}" \
-DPYTHON_CMD="python" \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_INSTALL_LIBDIR=/usr/lib ..
make
# Install just those bindings
make -C "${srcdir}/${pkgbase}/build/src/python" DESTDIR="${pkgdir}" install
}
package_python2-bcc-git() {
pkgdesc='BPF Compiler Collection - Python 2 bindings - latest git code'
arch=('any')
depends=('bcc-git' 'python2')
makedepends=('cmake')
cd "${srcdir}/${pkgbase}/build"
# Force a quick python2 binding build (C library is already buidl)
cmake -DPYTHON_CMD="python2" \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_INSTALL_LIBDIR=/usr/lib ..
make
# Install just those bindings
make -C "${srcdir}/${pkgbase}/build/src/python" DESTDIR="${pkgdir}" install
}
|