summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 4c7d6175b8522a5987f3f1dcc0950381d9b94bfb (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=bcftools-git
pkgver=1.10.2.r123.gdc26549
pkgrel=1
pkgdesc="Tools for variant calling and manipulating VCFs and BCFs"
arch=('i686' 'x86_64')
url="https://samtools.github.io/bcftools/"
license=('custom')
depends=('glibc' 'gsl' 'htslib' 'zlib')
makedepends=('git')
optdepends=('python')
provides=('bcftools')
conflicts=('bcftools')
source=("git+https://github.com/samtools/bcftools.git")
sha256sums=('SKIP')


pkgver() {
  cd "bcftools"

  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "bcftools"

  autoreconf -fi
  ./configure \
    --prefix="/usr" \
    --with-bcf-plugin-dir=/usr/lib/bcftools \
    --enable-libgsl
  make
}

check() {
  cd "bcftools"

  #make check
}

package() {
  cd "bcftools"

  make DESTDIR="$pkgdir" install
  install -Dm644 "LICENSE" -t "$pkgdir/usr/share/licenses/bcftools"
}