PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34

# Maintainer: Andrew Hills <ahills@ednos.net>
pkgname=beard
pkgver=0.2
pkgrel=1
pkgdesc="A simple hibernation daemon"
arch=('any')
url="https://github.com/ahills/$pkgname"
license=('custom:unlicense')
depends=('pm-utils' 'coreutils' 'util-linux' 'syslog-ng')
backup=('etc/conf.d/beard')
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz"
        beard.service)
md5sums=('5af92e22e27d497db2ccee823140bb84'
         '72a17538035df4c120c8b6fed112d78e')
validpgpkeys=()

package() {
	cd "$pkgname-$pkgver"
	make PREFIX=/usr DESTDIR="$pkgdir/" install
	# Correct /usr/sbin to /usr/bin
	mv "$pkgdir"/usr/sbin "$pkgdir"/usr/bin

	# Makefile doesn't install these
	mkdir -p "$pkgdir"/etc/conf.d
	install -m0644 beard.conf "$pkgdir"/etc/conf.d/beard
	mkdir -p "$pkgdir"/usr/share/doc/beard
	install -m0644 README.md "$pkgdir"/usr/share/doc/beard/README.md
	mkdir -p "$pkgdir"/usr/share/licenses/beard
	install -m0644 LICENSE "$pkgdir"/usr/share/licenses/beard/LICENSE

	# systemd service file
	mkdir -p "$pkgdir"/usr/lib/systemd/system
	install -m0644 "$srcdir"/beard.service "$pkgdir"/usr/lib/systemd/system/beard.service
}