blob: d65158a8e69fbdb17602d2a08e88eb461ecf41c8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
pkgname=bettercap-git
pkgver=1.5.3.775.097478a
pkgrel=1
pkgdesc='Complete, modular, portable and easily extensible MITM framework'
url='https://github.com/evilsocket/bettercap'
arch=('any')
license=('GPL3')
depends=('ruby' 'ruby-network_interface' 'ruby-pcaprub' 'ruby-packetfu' 'ruby-colorize' 'ruby-net-dns' 'ruby-em-proxy' 'ruby-rubydns')
makedepends=('git')
provides=('bettercap')
conflicts=('bettercap')
options=('!emptydirs')
source=(${pkgname}::git+https://github.com/evilsocket/bettercap)
sha512sums=('SKIP')
pkgver() {
cd ${pkgname}
printf "%s.%s.%s" "$(git describe --tags --abbrev=0|cut -dv -f2)" \
"$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd ${pkgname}
gem build bettercap.gemspec
}
package() {
cd ${pkgname}
local _gemdir="$(gem env gemdir)"
gem install --ignore-dependencies --no-user-install -i "${pkgdir}/${_gemdir}" -n "${pkgdir}/usr/bin" bettercap*.gem
install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
install -Dm 644 LICENSE.md "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
# vim: ts=2 sw=2 et:
|