blob: d6f777bb324b0daca1fb5cecda7e9fcb5e555a47 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: Shatur95 <genaloner@gmail.com>
# Co-Maintainer: Mark Wagie <mark dot wagie at tutanota dot com>
# Contributor: ful1e5 <kaizmandhu at gmail dot com>
pkgname=bibata-cursor-theme
pkgver=1.0.2
pkgrel=1
pkgdesc="Material Based Cursor Theme"
arch=('any')
url="https://github.com/ful1e5/Bibata_Cursor"
license=('GPL3')
depends=('libxcursor' 'libpng')
makedepends=('python-clickgen')
options=('!strip')
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz"
"$pkgname-bitmaps-$pkgver.zip::$url/releases/download/v$pkgver/bitmaps.zip")
noextract=("$pkgname-bitmaps-$pkgver.zip")
sha256sums=('f119f770a79eb53958c9176275a4d31e99c59bf3b2f750547a9e48631fbb2ad7'
'2e5a7967791f0c71c5aed2d911952ead6fbc1f3b755d39ade82d6f18ce4a1e21')
prepare() {
cd Bibata_Cursor-$pkgver
mkdir -p bitmaps
bsdtar -xf "$srcdir/$pkgname-bitmaps-$pkgver.zip" -C bitmaps
rm -rf themes
}
build() {
cd Bibata_Cursor-$pkgver
python build.py --x11
}
package() {
cd Bibata_Cursor-$pkgver
install -d "$pkgdir"/usr/share/icons
cp -r themes/Bibata-* "$pkgdir"/usr/share/icons
chmod -R 755 "$pkgdir"/usr/share/icons/Bibata-*
}
|