summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 9984dbf8c4835427acd7a9fbe41b297cf26798e3 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
# Maintainer: Mark Wagie <mark dot wagie at tutanota dot com>
pkgname=bibata-extra-cursor-theme
pkgver=1.0.1
pkgrel=1
pkgdesc="Material Based Cursor Theme: More Bibata!"
arch=('any')
url="https://github.com/ful1e5/Bibata_Extra_Cursor"
license=('GPL3')
depends=('libxcursor' 'libpng')
makedepends=('python-clickgen')
provides=("${pkgname%-theme}")
conflicts=("${pkgname%-theme}")
options=('!strip')
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz"
        "$pkgname-bitmaps-$pkgver.zip::$url/releases/download/v$pkgver/bitmaps.zip")
noextract=("$pkgname-bitmaps-$pkgver.zip")
sha256sums=('e5c2b0e3960f10df8281681a5ada914f2cf89480abc0c17fd8b677015a9d6ea7'
            'b44127f133ba12a09a389bda500ed6f4e2acb62ab3e1d906562ff2512c25c16d')

prepare() {
	cd Bibata_Extra_Cursor-$pkgver
	mkdir -p bitmaps
	bsdtar -xf "$srcdir/$pkgname-bitmaps-$pkgver.zip" -C bitmaps

	rm -rf themes
}

build() {
	cd Bibata_Extra_Cursor-$pkgver/builder
	make build_unix
}

package() {
	cd Bibata_Extra_Cursor-$pkgver
	install -d "$pkgdir"/usr/share/icons
	cp -r themes/Bibata-* "$pkgdir"/usr/share/icons
}