PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Maintainer: Yakov Till <yakov.till@gmail.com>
pkgname=bibavpn
pkgver=1.5.2
pkgrel=1
pkgdesc="DPI-resistant SOCKS5/HTTP tunnel over TLS+WebSocket (server, client, invite minter)"
arch=('x86_64')
url="https://github.com/Eljaja/BibaVPN"
license=('MIT')
# ring ships prebuilt asm/C objects; makepkg LTO turns them into bitcode that
# lld cannot resolve against the Rust crate -> undefined ring_core_* symbols.
options=('!lto')
depends=('gcc-libs')
makedepends=('cargo' 'git')
source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('4d390f053be1d98c0161e7f256680876f2042a79d7488c9f1d56e0fb98344ffe')

latestver() {
    git ls-remote --tags --refs "$url" |
        sed -nE 's@.*refs/tags/v([0-9]+(\.[0-9]+)*)$@\1@p' | sort -V | tail -1
}

prepare() {
    cd "BibaVPN-$pkgver"
    export RUSTUP_TOOLCHAIN=stable
    cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}

build() {
    cd "BibaVPN-$pkgver"
    export RUSTUP_TOOLCHAIN=stable CARGO_TARGET_DIR=target
    cargo build --frozen --release -p bibavpn
}

package() {
    cd "BibaVPN-$pkgver"
    install -Dm755 -t "$pkgdir/usr/bin" \
        target/release/bibavpn-server \
        target/release/bibavpn-client \
        target/release/bibavpn-mint-invite
    install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}