PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer: Dan Griffiths <me at evertiro dot com>

pkgname=bibisco
pkgver=4.0.1
pkgrel=1
pkgdesc='Novel writing software for authors'
arch=('x86_64')
url='https://bibisco.com'
license=('MIT')
conflicts=('bibisco-ce')
depends=(
	'alsa-lib'
	'at-spi2-core'
	'gtk3'
	'libcups'
	'nodejs'
	'nspr'
	'nss'
	'pango'
)
source=(
	# Download the zip file and place in the same directory as this file.
	"local://bibisco-linux-x64-${pkgver}-SE.zip"
	${pkgname}.desktop
)
sha256sums=(
	'0c3a86eebcca3d63775c819ad4f595804e81cfc0d4cf2c85f90e6b26dc483db8'
	'c67436460914778542cb8bf82b77ebbc0b3860fa68ff64efdf50a76af7aa2f14'
)
package()
{
	_unpacked_dirname="bibisco-linux-x64-${pkgver}-SE"

	# data
	install -d "${pkgdir}/opt" "${pkgdir}/usr/bin"
	chmod 755 "${srcdir}/${_unpacked_dirname}" # Fix incorrect permissions
	cp -aT "${srcdir}/${_unpacked_dirname}" "${pkgdir}/opt/${pkgname}"
	ln -s "/opt/${pkgname}/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"

	# desktop integration
	install -Dm644 "${srcdir}/${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
	install -d "${pkgdir}/usr/share/pixmaps"
	ln -s "/opt/${pkgname}/resources/app/assets/icons/linux/bibisco-circle-hr.png" "${pkgdir}/usr/share/pixmaps/${pkgname}.png"

	# legal
	install -Dm644 -t "${pkgdir}/usr/share/licenses/${pkgname}" "${srcdir}/${_unpacked_dirname}/LICENSE" "${srcdir}/${_unpacked_dirname}/LICENSES.chromium.html"
}