blob: 3e79f17d25a6d394209214fbdc5b2b4294cb00a7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Chris Charabaruk <chris [at] charabaruk [dot] net>
pkgname=biblioteq
pkgver=2026.09.15
pkgrel=1
pkgdesc="Qt application for library catalog and membership management"
arch=('x86_64')
url="https://textbrowser.github.io/biblioteq/"
license=('BSD-3-Clause')
depends=('qt6-base'
'qt6-multimedia'
'qt6-webengine'
'poppler-qt6'
'yaz'
'gcc-libs')
makedepends=('qt6-tools')
optdepends=('postgresql-libs: PostgreSQL database connectivity')
source=("$pkgname-$pkgver.tar.gz::https://github.com/textbrowser/biblioteq/archive/$pkgver.tar.gz")
sha256sums=('83ea0368e50b77740f32d049e40cbc0bd460b197c8c5c38a25a19e13f3bff7fe')
build() {
cd "$pkgname-$pkgver"
qmake6 -o Makefile biblioteq.pro
make
}
package() {
cd "$pkgname-$pkgver"
install -d "$pkgdir/opt/$pkgname"
install -t "$pkgdir/opt/$pkgname" ./BiblioteQ ./biblioteq.sh
install -m 644 -t "$pkgdir/opt/$pkgname" ./biblioteq.conf ./Icons/book.png
# Install supporting data (SQLite and CSV templates)
install -Dm 644 -t "$pkgdir/opt/$pkgname/Data" ./Data/*
# Install SQL scripts for PostgreSQL
install -Dm 644 -t "$pkgdir/opt/$pkgname/SQL" ./SQL/*
chmod a+x "$pkgdir/opt/$pkgname/SQL"/*.sh
# Install documentation (except for code docs)
install -d "$pkgdir/opt/$pkgname/Documentation"
cp -pr ./Documentation/* "$pkgdir/opt/$pkgname/Documentation"
rm -fr "$pkgdir/opt/$pkgname/Documentation/Doxygen"
chown -RP root:root "$pkgdir/opt/$pkgname/Documentation"
install -d "$pkgdir/usr/bin"
ln -s "/opt/$pkgname/$pkgname.sh" "$pkgdir/usr/bin/$pkgname"
install -Dm 644 -t "$pkgdir/usr/share/applications" ./Distributions/biblioteq.desktop
install -Dm 644 -t "$pkgdir/usr/share/licenses/$pkgname/" ./LICENSE
}
|