blob: e94487eb43b5514898c3fa63d91957617e162ba9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Emmanuel Gil Peyrot <linkmauve@linkmauve.fr>
_pkgname=biboumi
pkgname="$_pkgname-git"
pkgver=r522.37fd6ff
pkgrel=1
pkgdesc="XMPP gateway to IRC"
arch=('i686' 'x86_64' 'armv7h')
url="http://biboumi.louiz.org/"
license=('ZLIB')
depends=('expat' 'libidn' 'c-ares' 'botan' 'litesql')
makedepends=('git' 'cmake' 'ruby-ronn')
provides=("$_pkgname=1.99")
conflicts=("$_pkgname")
backup=("etc/$_pkgname/$_pkgname.cfg")
source=("$_pkgname::git://git.louiz.org/biboumi")
md5sums=('SKIP')
pkgver() {
cd "$srcdir/$_pkgname"
echo "r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}
prepare() {
cd "$srcdir/$_pkgname"
mkdir -p build
}
build() {
cd "$srcdir/$_pkgname/build"
cmake -DCMAKE_BUILD_TYPE=Release -DCMAKE_INSTALL_PREFIX=/usr ..
make biboumi
}
package() {
cd "$srcdir/$_pkgname/build"
make DESTDIR="$pkgdir/" install
cd ..
install -Dm644 COPYING "$pkgdir/usr/share/licenses/$_pkgname/LICENSE"
install -Dm644 doc/biboumi.1.md "$pkgdir/usr/share/doc/$_pkgname/$_pkgname.md"
}
|