summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: eef859025a86fd804fcf33ba14100d64693dad22 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
# Maintainer: Stefan Husmann <stefan-husmann@t-online.de>
pkgname=bibtool-git
pkgver=2.68.r14.g43de68a
pkgrel=1
pkgdesc="Command line manipulation of BibTeX files - from git-repo"
arch=('i686' 'x86_64')
url="http://www.gerd-neugebauer.de/software/TeX/BibTool/"
license=('GPL')
depends=('texlive-bin' 'glibc')
makedepends=('git' 'texlive-core')
provides=('bibtool')
conflicts=('bibtool')
source=("git+https://github.com/ge-ne/bibtool")
md5sums=('SKIP')

pkgver() {
  cd ${pkgname%-git}
  git describe --tags | cut -c9- | tr _ . | sed 's+-+.r+' | tr - .
}

build() {
  cd ${pkgname%-git}
  autoreconf
  ./configure --prefix=/usr
  make
  cd doc
  make
}

package() {
  cd ${pkgname%-git}
  install -d "$pkgdir"/usr/bin "$pkgdir"/usr/share/docs/$pkgname "$pkgdir"/usr/share/man/man1
  make INSTALLPREFIX="$pkgdir/" install
  cd doc
  for _i in *.pdf
  do
    install -Dm644 ${_i} "$pkgdir"/usr/share/docs/$pkgname/${_i}
  done
  install -Dm644 ${pkgname%-git}.1 "$pkgdir"/usr/share/man/man1
}