blob: cb87ec8351cf07aa7729e1ae577a1c247bbbf2a1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Maintainer: Misaka13514 <Misaka13514 at gmail dot com>
# Contributor: Sébastien Luttringer
# Contributor: Carl Smedstad <carsme@archlinux.org>
pkgname=bird2
_pkgname=bird
pkgver=2.18
pkgrel=1
pkgdesc='RIP, OSPF, BGP, MPLS, BFD, Babel routing daemon'
arch=('x86_64')
url='https://bird.network.cz/'
license=('GPL-2.0-or-later')
depends=('glibc' 'readline' 'ncurses' 'libssh')
makedepends=('linuxdoc-tools' 'texlive-basic' 'texlive-latex' 'texlive-latexrecommended' 'texlive-latexextra')
provides=($_pkgname)
conflicts=($_pkgname)
replaces=('bird6')
backup=('etc/bird.conf')
options=(!emptydirs)
source=("https://gitlab.nic.cz/labs/bird/-/archive/v$pkgver/$_pkgname-v$pkgver.tar.gz"
'bird.service')
sha256sums=('fa0785d36200a1950b85d9806360648b7c85cd4498088ede3f95ca031b1d70ee'
'4aa1e8d41229badd276aa3747f613e7df34761892add2258c63bdb5097dfeb2b')
prepare() {
cd $_pkgname-v$pkgver
sed -i 's|docdir=@prefix@/doc|docdir=@docdir@|g' Makefile.in
autoreconf -vif
}
build() {
cd $_pkgname-v$pkgver
./configure \
--prefix=/usr \
--sbindir=/usr/bin \
--sysconfdir=/etc \
--localstatedir=/var \
--runstatedir=/run/$_pkgname \
--docdir=/usr/share/doc/$_pkgname
make
make docs
}
check() {
cd $_pkgname-v$pkgver
make check
}
package() {
cd $_pkgname-v$pkgver
make DESTDIR="$pkgdir" install
make DESTDIR="$pkgdir" install-docs
# systemd
install -vD -m 644 -t "$pkgdir/usr/lib/systemd/system" "$srcdir/bird.service"
}
# vim:set ts=2 sw=2 et:
|