blob: 8597fbe33d4cd062195da8c00dcfe9f556f77932 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: David Parrish <daveparrish@tutanota.com>
# Co-Maintainer: Felix Golatofski <contact@xdfr.de>
pkgname=bisq
pkgver=1.9.5
pkgrel=1
pkgdesc="Cross-platform desktop application that allows users to trade national currency (dollars, euros, etc) for bitcoin without relying on centralized exchanges"
arch=('any')
url="https://bisq.network"
license=('AGPL3')
depends=('jdk11-openjdk')
makedepends=('jdk11-openjdk')
source=("$pkgname-$pkgver.tar.gz::https://github.com/bisq-network/bisq/archive/v${pkgver}.tar.gz"
"https://github.com/bisq-network/bisq/releases/download/v${pkgver}/bisq-${pkgver}.tar.gz.asc"
"bisq.desktop")
sha256sums=('8feb8870b7b2ff1c3b4bbff48c3f2bc8386a88e552be8acf88ffafa9276a3f53'
'SKIP'
'687d643fbe84660c3ebfe6270de98214f2e3ea791cb1d07d96d7ed889d61d406')
validpgpkeys=('CB36D7D2EBB2E35D9B75500BCD5DC1C529CDFD3B') # Christoph Atteneder
_binname=Bisq
conflicts=("bisq-bin" "bisq-git")
provides=("bisq")
build() {
cd "${srcdir}/${pkgname}-${pkgver}" || exit
msg2 "Building bisq..."
./gradlew clean :desktop:build -Dorg.gradle.java.home=/usr/lib/jvm/java-11-openjdk -x test
}
package() {
# Install executable.
install -d "${pkgdir}/opt/bisq"
cp -r "${srcdir}/${pkgname}-${pkgver}/desktop/build/app/"* "${pkgdir}/opt/bisq"
cp -r "${srcdir}/${pkgname}-${pkgver}/bisq-desktop" "${pkgdir}/opt/bisq/"
install -d "${pkgdir}/usr/bin"
ln -s "/opt/bisq/bisq-desktop" "${pkgdir}/usr/bin/bisq-desktop"
# Install desktop launcher.
install -Dm644 bisq.desktop "${pkgdir}/usr/share/applications/bisq.desktop"
install -Dm644 "${srcdir}/${pkgname}-${pkgver}/desktop/package/linux/icon.png" "${pkgdir}/usr/share/pixmaps/bisq.png"
}
|