summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 0b5b40b43d3a9626e9d3af60a7f995274103d296 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
# Maintainer: Joseph R. Quinn <quinn.josephr@protonmail.com>
pkgname=bitbucket-cli
pkgver=1.1.0
pkgrel=1
pkgdesc="A powerful command-line interface for Bitbucket Cloud - manage repos, PRs, issues, and pipelines from your terminal with OAuth 2.0"
arch=('x86_64' 'aarch64')
url="https://github.com/quinnjr/bitbucket-cli"
license=('MIT')
depends=('dbus' 'gcc-libs' 'glibc')
makedepends=('cargo' 'dbus' 'pkgconf')
options=('!lto')
optdepends=(
    'gnome-keyring: store credentials in GNOME Keyring via Secret Service'
    'kwallet: store credentials in KDE Wallet via Secret Service'
)
provides=('bitbucket')
source=("$pkgname-$pkgver.tar.gz::https://github.com/quinnjr/bitbucket-cli/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('c0f6c0f236dc4f669a022f43fd416dea685dd9be60e619dbe448f073f41287bd')

_rust_env() {
    export RUSTUP_TOOLCHAIN=stable
    # Upstream enables release LTO; disable for distro builds to avoid LLVM
    # bitcode mismatches when CC points at system clang (LLVM 22) vs rustc (LLVM 21).
    export CARGO_PROFILE_RELEASE_LTO=false
    unset CC CXX CFLAGS CXXFLAGS LDFLAGS
}

prepare() {
    cd "$pkgname-$pkgver"
    _rust_env
    cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}

build() {
    cd "$pkgname-$pkgver"
    _rust_env
    export CARGO_TARGET_DIR=target
    cargo build --frozen --release
}

check() {
    cd "$pkgname-$pkgver"
    _rust_env
    export CARGO_TARGET_DIR=target
    cargo test --frozen --release
}

package() {
    cd "$pkgname-$pkgver"
    install -Dm755 "target/release/bitbucket" "$pkgdir/usr/bin/bitbucket"
    install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
}