blob: d2d22fa3d34aaefe376c1c17d092ad6a4dcdddb9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Maintainer: Tom Zander
pkgname=bitcoin-classic
pkgver=1.2.3
pkgrel=1
pkgdesc='Bitcoin Classic with bitcoind, bitcoin-cli, bitcoin-tx, and bitcoin-qt'
arch=('i686' 'x86_64')
url="https://bitcoinclassic.com/"
license=('MIT')
depends=('boost-libs' 'libevent' 'desktop-file-utils' 'qt5-base' 'protobuf' 'openssl' 'miniupnpc' 'zeromq' 'qrencode')
makedepends=('boost' 'qt5-tools')
provides=('bitcoin-daemon' 'bitcoin-cli' 'bitcoin-qt' 'bitcoin-tx')
conflicts=('bitcoin-daemon' 'bitcoin-cli' 'bitcoin-qt' 'bitcoin-tx')
install=bitcoin.install
backup=("etc/bitcoin/bitcoin.conf")
source=(${pkgname}-${pkgver}.tar.gz::"https://github.com/bitcoinclassic/bitcoinclassic/archive/v${pkgver}.tar.gz"
"bitcoin.logrotate"
"bitcoin.conf")
sha256sums=('3eef89d633f503749267f0ff64135d7e8bc187b8fd78c3d849ec19a2b0c4d4ff'
"7bf4bdad419c1ee30b88c7e4190707c5ff250da8b23d68d5adf14043f8e2ac73"
"c8787560c6423605796c8d3e080cb522ed849cea12b5c23293c22e405a015a53")
build() {
cd "bitcoinclassic-$pkgver"
./autogen.sh
./configure --prefix=/usr --with-incompatible-bdb --with-gui=qt5 --enable-hardening \
--enable-reduce-exports --disable-gui-tests --disable-maintainer-mode
make
}
check() {
"bitcoinclassic-$pkgver/src/test/test_bitcoin"
}
package() {
cd "bitcoinclassic-$pkgver"
install -Dm755 "src/qt/bitcoin-qt" "$pkgdir/usr/bin/bitcoin-qt"
install -Dm644 "share/pixmaps/bitcoin128.png" "$pkgdir/usr/share/pixmaps/bitcoin128.png"
install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
install -Dm644 "contrib/debian/bitcoin-qt.desktop" "$pkgdir/usr/share/applications/bitcoin.desktop"
install -Dm644 "contrib/debian/examples/bitcoin.conf"\
-t "$pkgdir/usr/share/doc/bitcoin/examples"
install -Dm644 "contrib/debian/manpages/bitcoind.1"\
-t "$pkgdir/usr/share/man/man1"
install -Dm644 "contrib/debian/manpages/bitcoin.conf.5"\
-t "$pkgdir/usr/share/man/man5"
install -Dm 664 "$srcdir/bitcoin.conf" -t "$pkgdir/etc/bitcoin"
sed 's/python2/python/' <share/rpcuser/rpcuser.py >rpcuser.py
install -Dm 755 rpcuser.py -t "$pkgdir/etc/bitcoin"
install -Dm 644 "contrib/init/bitcoind.service" -t "$pkgdir/usr/lib/systemd/system"
install -Dm 644 "$srcdir/bitcoin.logrotate" "$pkgdir/etc/logrotate.d/bitcoin"
install -Dm 644 contrib/bitcoind.bash-completion \
"$pkgdir/usr/share/bash-completion/completions/bitcoind"
install -Dm755 "src/bitcoind" "src/bitcoin-cli" "src/bitcoin-tx" -t "$pkgdir/usr/bin"
}
|