blob: 07fa3d754ca0823e66fd784860f6fbecaba3a51d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: KokaKiwi <kokakiwi+aur at kokakiwi dot net>
pkgname=bkmr
pkgver=0.8.0
# _pkgrev=982145d8ea36d9a78d7c7f828ca5a68f7aa9b524
# _pkgref=$_pkgrev
_pkgrev=$pkgver
_pkgref="refs/tags/v$_pkgrev"
pkgrel=1
pkgdesc='Ultrafast Bookmark Manager and Launcher'
url='https://github.com/sysid/bkmr'
license=('custom:BSD-3-Clause')
arch=('x86_64' 'i686' 'arm' 'aarch64')
depends=('gcc-libs' 'openssl')
makedepends=('cargo')
source=("$pkgname-$pkgver.tar.gz::https://github.com/sysid/bkmr/archive/$_pkgref.tar.gz"
Cargo.lock)
sha256sums=('766ef127b1e347fa60293dd66ea17f5076921e3be2c3a96e8de503dcbe71411e'
'471dc9a27646fb18e485032a845883d723d9d4c224527c7866c003e381f43701')
b2sums=('5567e835342a65971520fc513e32c4ea0c600f1933a185f7c32717715f51eedd379fc20ed93cdf613a993ec41b2510867bb2239cf2bb8841edee8516f0533e7a'
'9c45398d44a966d85e675894ecb51abbef797bb88f69c867377bc84caeace4f6ac3f39b3bafffdf5d2a7940646945a4cdcb2bd6613bd5cb299c19d4ad1d1842e')
case $CARCH in
x86_64|i686|aarch64)
_target="$CARCH-unknown-linux-gnu" ;;
arm)
_target="arm-unknown-linux-gnueabi" ;;
esac
prepare() {
cd "$pkgname-$_pkgrev"
ln -sf "$srcdir/Cargo.lock" bkmr/Cargo.lock
cargo fetch --manifest-path bkmr/Cargo.toml --locked --target $_target
}
build() {
cd "$pkgname-$_pkgrev"
CARGO_TARGET_DIR='target' \
cargo build --manifest-path bkmr/Cargo.toml --frozen --release
}
package() {
cd "$pkgname-$_pkgrev"
install -Dm0755 -t "$pkgdir/usr/bin" \
target/release/bkmr
install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}
|