PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

# Maintainer: Rafael Silva <perigoso@riseup.net>

pkgbase='black-magic-debug-git'
pkgname=(black-magic-debug-app-git black-magic-debug-udev-git)
pkgver=1.9.0.rc1.r33.g302c8b53
pkgrel=1
pkgdesc='Plug&Play in application debugger for microcontrollers'
arch=('any')
url='https://black-magic.org'
license=('GPL')
makedepends=('git' 'hidapi' 'python')
options=(!strip)
source=("git+https://github.com/blackmagic-debug/blackmagic.git")
sha256sums=('SKIP')

pkgver() {
    cd "blackmagic"

    git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    cd "blackmagic"

    make PROBE_HOST=hosted ENABLE_RTT=1
}

package_black-magic-debug-udev-git() {
    cd "blackmagic"

    install -Dm 644 driver/99-blackmagic-uucp.rules "${pkgdir}"/usr/lib/udev/rules.d/99-blackmagic-uucp.rules
}

package_black-magic-debug-app-git() {
    cd "blackmagic"

    depends=('libusb' 'libftdi' 'libhidapi-libusb.so')

    install -Dm 755 src/blackmagic "${pkgdir}"/usr/bin/blackmagic
}