blob: 2f6360987e03fc90aec6bfdb5e4ed1149003efda (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
pkgname="blend2d"
pkgver=0.21.2
pkgrel=1
pkgdesc="A high-performance 2D vector graphics engine written in C++"
arch=('aarch64' 'armv7h' 'i686' 'x86_64')
url="https://blend2d.com"
license=('Zlib')
depends=(
'glibc'
)
makedepends=(
'clang'
'cmake>=3.19'
)
provides=(
"lib${pkgname}.so"
)
_pkgsrc="${pkgname}-${pkgver}"
source=("${_pkgsrc}.tar.gz::${url}/download/${_pkgsrc}.tar.gz")
sha256sums=('234ba57a64153c96885a6271f15fdcf6c594ac8cb03adaad19abb8d3b2b533fa')
b2sums=('284c819c87abcba340d2ff9b3f9ca3103270ccddeeb081b18f1381d33d7ae114d43cecd1f4b8fc99ffae9750b973b6d4b45f9be344122218fb6f5e093b1ebf32')
prepare() {
cd "${srcdir}/${pkgname}"
sed -i '/-O2/d' 'CMakeLists.txt'
}
build() {
export CC="clang"
export CXX="clang++"
local cmake_options=(
-G 'Unix Makefiles'
-B "${pkgname}/build"
-S "${pkgname}"
-W no-dev
-D CMAKE_BUILD_TYPE:STRING='None'
-D CMAKE_INSTALL_PREFIX:PATH='/usr'
-D BLEND2D_TEST:BOOL=TRUE
-D BLEND2D_EMBED:BOOL=FALSE
-D BLEND2D_STATIC:BOOL=FALSE
-D BLEND2D_EXTERNAL_ASMJIT:BOOL=FALSE
)
cd "${srcdir}"
cmake "${cmake_options[@]}"
cmake --build "${pkgname}/build"
}
check() {
local excluded_tests=""
local ctest_flags=(
--test-dir "${pkgname}/build"
--output-on-failure
--parallel "$(nproc)"
--exclude-regex "${excluded_tests}"
)
cd "${srcdir}"
ctest "${ctest_flags[@]}"
}
package() {
cd "${srcdir}"
DESTDIR="${pkgdir}" cmake --install "${pkgname}/build"
cd "${pkgname}"
install -vDm644 "README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
install -vDm644 "LICENSE.md" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.md"
}
|