blob: 2b13ec2ff2de29badb9a90f630be1ef2917568cd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: Roberto Nobrega <rwnobrega@gmail.com>
# Contributor: Viktor Drobot (aka dviktor) linux776 [at] gmail [dot] com
# Contributor: Balló György <ballogyor+arch at gmail dot com>
# Contributor: TDY <tdy@gmx.com>
# Contributor: dcraven <dcraven@gmail.com>
pkgname=bless-git
_gitname=bless
pkgver=r169.db747af
pkgrel=1
pkgdesc="High-quality, full-featured hex editor (git version)"
arch=('any')
url="https://web.archive.org/web/20170503150524/http://home.gna.org/bless/"
license=('GPL')
depends=('gtk-sharp-2')
conflicts=('bless')
makedepends=('rarian' 'automake')
source=("git://github.com/afrantzis/bless.git")
sha256sums=('SKIP')
pkgver() {
cd ${srcdir}/${_gitname}/
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd ${srcdir}/${_gitname}
./autogen.sh
}
build() {
cd ${srcdir}/${_gitname}
./configure --prefix=/usr
make
}
package() {
cd ${srcdir}/${_gitname}
make DESTDIR="${pkgdir}" MKDIR_P='mkdir -p' install
}
|